A signal of random numbers every second where the first seed is a timestamp

SignalOfRandomNum.elm

module SignalOfRandomNum where

import Graphics.Element as GE
import Time
import Random
import Maybe exposing (..)

randomIntSignal : Int -> Int -> Signal Time.Time -> Signal Int
randomIntSignal lo hi inputSignal =
  let
    intGen = Random.int lo hi

    nextRandom seed =
      seed
      |> Random.generate intGen
      |> Just

    update time accu =
      case accu of
        Just (_, seed) ->
          seed
          |> nextRandom
        Nothing ->
          round time
          |> Random.initialSeed
          |> nextRandom
  in
    inputSignal
    |> Signal.foldp update Nothing
    |> Signal.map (\maybe->
        case maybe of
          Just (n,_)  -> n
          Nothing -> -1 )


signalOfRandomIntEverySecond :  Signal Int
signalOfRandomIntEverySecond =
  Time.every Time.second |> randomIntSignal 1 100

main : Signal GE.Element
main =
  Signal.map GE.show signalOfRandomIntEverySecond