gen-hoogle.hoon

/+  auto=language-server-complete,
    easy-print=language-server-easy-print
:-  %say
|=  [* [query=cord ~] ~]
:-  %tang
=/  lib=type
  -:!>(..zuse)
|^
=/  specs
  %+  sear
    |=  sps=(list spec)
    ^-  (unit spec)
    ?~  sps  ~
    `[%bccl i.sps t.sps]
  %+  most  ace
  till:vast
=/  [sample=spec return=spec]
  %+  rash  query
  ;~  (glue ;~(plug ace hep gar ace))
    specs
    specs
  ==
^-  tang
%+  murn
  (get-identifiers:auto -:!>(..zuse))
|=  [name=term =type]
^-  (unit tank)
?:  (~(has in molds) name)  ~
=/  =hoon
  :+  %kthp
    return
  :+  %cnhp
    wing+~[name]
  [%kttr sample]
=/  res
  (mule |.((~(mint ut lib) %noun hoon)))
?-  -.res
  %|  ~
::
    %&
  =/  type-desc
    ~(ram re ~(duck easy-print type))
  `leaf+"{(trip name)}: {type-desc}"
==
++  molds
  ~+
  %-  sy
  ^-  (list term)
  %+  murn
    (get-identifiers:auto lib)
  |=  [name=term =type]
  ^-  (unit term)
  =/  =hoon
    :+  %kthp  [%like ~[%mold] ~]
    wing+~[name]
  =/  res
    (mule |.((~(mint ut lib) %noun hoon)))
  ?-  -.res
    %&  `name
    %|  ~
  ==
--