create-stats.xq

xquery version "3.1";

map {
  "date" : current-dateTime(),
  "packages" : array {
    for $get-package-event in collection("/db/apps/public-repo-data/logs")//type[.="get-package"]/..
    group by $name := $get-package-event/package-name/string()
    let $event-count := count($get-package-event) 
    order by $event-count descending
    return
      map { 
        "name" : $name[1],
        "downloads": $event-count,
        "versions": array {
          for $version in $get-package-event/package-version
          group by $s := $version/string()
          let $version-count := count($version)
          order by $version-count descending
          return map { "version": $s[1], "downloads": $version-count }
        }
      }
  }
}
=> serialize(map {"method": "json"})

events-csv.xq

xquery version "3.1";

``[name,version,date`{
for $evt in collection("/db/apps/public-repo-data/logs")//type[.="get-package"]/..
return ``[
`{$evt/package-name}`,`{$evt/package-version}`,`{$evt/dateTime}`]``}`]``

events-list.xq

xquery version "3.1";

array {
    for $get-package-event in collection("/db/apps/public-repo-data/logs")//type[.="get-package"]/..
    return map {
        "name" : $get-package-event/package-name/string(),
        "version" : $get-package-event/package-version/string(),
        "date" : $get-package-event/dateTime/string()
    }
}
=> serialize(map {"method": "json"})

Nice! In events-csv.xq, the /string() calls are extraneous, since the string constructor atomizes the nodes.

Thanks for the hint!