corrector.d

import std.stdio, std.range, std.algorithm, std.conv, std.string, std.file;

immutable letters = "abcdefghijklmnopqrstuvwxyz"d;

auto replaces(S)(S word) {
  return word.length.iota.map!(i =>
           letters.length.iota.map!(j =>
             word[0 .. i].chain(letters[j .. j+1], word[i+1 .. $])))
         .joiner;
}

auto insertions(S)(S word) {
  return (word.length + 1).iota.map!(i =>
              letters.length.iota.map!(j =>
                word[0 .. i].chain(letters[j .. j+1], word[i .. $])))
         .joiner;
}

auto deletions(S)(S word) {
  return word.length.iota.map!(i => word[0 .. i].chain(word[i+1 .. $]));
}

bool isFromDict(S, D)(auto ref S word, auto ref D dict) {
  dchar[256] buf = void;
  return !!(cast(dstring)buf[0 .. word.copy(buf[]).ptr - buf.ptr] in dict);
}

void main() {
  bool[dstring] dict;
  foreach (s; readText("/usr/share/dict/words").to!dstring.splitLines)
    dict[s] = true;
  writeln("inkorect"d.insertions.map!replaces.joiner
                     .filter!(w => w.isFromDict(dict)).array.sort.uniq!equal);
}