AppleScript droplet to file documents into specific Evernote notebooks

Evernote filing droplet.dmg

Notebook Name.applescript

-- Source code of an AppleScript droplet to file documents into specific Evernote notebooks
-- If you just want to run the code, download the DMG file
--
-- Get notebook name from name of droplet
-- See https://stackoverflow.com/questions/5770384/how-find-the-file-name-of-an-executing-applescript
on getMyName()
	local myName, tidSaved
	tell application "System Events"
		set myAlias to path to me -- alias to the file/bundle of the running script
		set myName to name of myAlias -- filename with extension, if any.
		if name extension of myAlias is not "" then -- strip away extension
			set {tidSaved, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {""}}
			set myName to items 1 through -(2 + (length of (get name extension of myAlias))) of myName as text
			set AppleScript's text item delimiters to tidSaved
		end if
	end tell
	return myName
end getMyName
-- Send drag-dropped files to Evernote, filing them in the appropriate notebook,
-- then moving each one to the trash
on open theDroppedItems
	set nbname to getMyName()
	repeat with a from 1 to length of theDroppedItems
		set theCurrentDroppedItem to item a of theDroppedItems
		set fileAlias to theCurrentDroppedItem as alias
		tell application "Finder"
			set fname to name of theCurrentDroppedItem
		end tell
		tell application "Evernote"
			create note title fname from file fileAlias notebook nbname
		end tell
		tell application "Finder"
			move fileAlias to trash
		end tell
	end repeat
end open