StatusChanger - Change status for iChat, Adium and Skype simultaneously

statuschanger.scpt

(*
 * StatusChanger - Change status for iChat, Adium and Skype simultaneously
 * by Luc-Olivier Dumais-Blais
 *)
script statusChanger
	set statusChosen to choose from list {"Available", "Busy", "Away", "Invisible", "Close apps"} ¬
		with title ¬
		"Change status on iChat, Adium and Skype" with prompt ¬
		"Choose an option : " default items ¬
		"Available" OK button name ¬
		"Change status" cancel button name ¬
		"Cancel" without multiple selections allowed
	if statusChosen is {"Available"} then
		tell application "Adium" to go available
		tell application "Skype" to send command "SET USERSTATUS ONLINE" script name "AppleScript status setter"
		tell application "iChat"
			set status to available
			set status message to ""
		end tell
	else if statusChosen is {"Busy"} then
		tell application "Adium" to go away with message "Busy"
		tell application "Skype" to send command "SET USERSTATUS DND" script name "AppleScript status setter"
		tell application "iChat"
			set status to away
			set status message to "Busy"
		end tell
	else if statusChosen is {"Away"} then
		tell application "Adium" to go away
		tell application "Skype" to send command "SET USERSTATUS AWAY" script name "AppleScript status setter"
		tell application "iChat"
			set status to away
			set status message to ""
		end tell
	else if statusChosen is {"Invisible"} then
		tell application "Adium" to go invisible
		tell application "Skype" to send command "SET USERSTATUS INVISIBLE" script name "AppleScript status setter"
		tell application "iChat"
			set status to invisible
			set status message to ""
		end tell
	else if statusChosen is {"Close apps"} then
		tell application "iChat" to quit
		tell application "Adium" to quit
		tell application "Skype" to quit
	end if
end script
tell statusChanger to run