How we are using the new resolver hook in ember.js master to auto-require most of our minispade modules

app_with_resolver.coffee

get = Ember.get
decamelize = Ember.String.decamelize
classify = Ember.String.classify

MinispadeResolver = Ember.DefaultResolver.extend
  logFailedLookups: true
  resolveTemplate: (parsedName)->
    resolvedTemplate = @_super(parsedName)
    unless resolvedTemplate
      try
        require "templates:#{parsedName.fullNameWithoutType}"
      catch e
        if @logFailedLookups
          Ember.Logger.warn("Could not find templates:#{parsedName.fullNameWithoutType}")
      resolvedTemplate = Ember.TEMPLATES[parsedName.fullNameWithoutType]
    resolvedTemplate
  parseName: (fullName)->
    parsedName = @_super(fullName)
    if parsedName.type == 'model'
      parsedName.suffix = ''
    else
      parsedName.suffix = parsedName.type
    parsedName
  resolveOther: (parsedName)->
    className = classify(parsedName.name) + classify(parsedName.suffix)
    factory = get(parsedName.root, className)
    unless factory
      try
        minispade.require "#{parsedName.type}s/#{decamelize(parsedName.name)}"
      catch e
        if @logFailedLookups
          Ember.Logger.warn("Could not find #{parsedName.fullName}")
      factory = get(parsedName.root, className)
    factory

window.App = Ember.Application.create
  resolver: MinispadeResolver