19.scd

// https://soundcloud.com/1vm/sc-170424-234237
// also clone this: http://github.com/lvm/BALC

(
~revBus = Bus.audio(s, 2);
~wahBus = Bus.audio(s, 2);
)

(
Pdef(\k,
  Pbind(
    \instrument, \kick,
    \amp, Pseq(
      (Bjorklund(4,16)!3).flat++
      [ 1, 0, 1, 0, 1, 0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 0 ]
      ,inf)*0.5,
    \midinote, 72,
    \dur, 1/4,
    \rel, 0.5,
    \out, ~revBus,
  )
).play(~t,quant:4);
Pdef(\h,
  Pbind(
    \instrument, \hat,
    \amp, Pseq(Bjorklund(4,16).rotate(2),inf)*0.5,
    \dur, 1/4,
    \rel, 0.1,
    \out, ~chan[3]
  )
).play(~t,quant:4);
Pdef(\bz,
  Pbind(
    \instrument, \bassy,
    \amp, 0.35,
    \dur, 1/4,
    \scale, \minor,
    \note, Pstutter(Pwhite(1,2, inf), Pseq([5, 9, 4, 0], inf)),
    \octave, Pwrand([3,4,5], [0.8, 0.15, 0.05], inf),
    \rq, Pwrand([0.5, 0.25, 0.125], [0.6, 0.25, 0.15], inf),
    \lctf, Pwhite(800, 8000, inf),
    \sus, 0.75,
    \rel, Pkey(\dur)+0.1,
    \out, ~chan[2]
  )
).play(~t, quant:4);
Pdef(\pl,
  Pbind(
    \instrument, \varsaw,
    \amp, 0.25,
    \dur, 16,
    \scale, \minor,
    \note, Pseq([
      [5,9,0],
      [9,0,4],
      [4,7,11],
      [0,3,7], 
    ],inf),
    \octave, 4,
    \atk, Pkey(\dur)/4,
    \sus, Pkey(\dur),
    \vib, 10,
    \pan, Pwhite(-0.75, 0.75, inf),
    \out, ~wahBus
  )
).play(~t,quant:4);
)

w = Synth(\wah, [\in, ~wahBus, \out, 0]);
w.set(\freq, 0.1);
w.set(\hi, 1000);

r = Synth(\reverb, [\in, ~revBus, \out, ~chan[1]]);
r.set(\room, 0.9);
r.set(\mix, 0.5);
r.set(\amp, 1.5);