λ Trim a leading and trailing, leading or trailing character repeatedly.

excel-lambda-trimChar.txt

trimChar = LAMBDA(str, [char], [mode],
    LET(
        charToTrim, IF(ISOMITTED(char), " ", LEFT(char, 1)),
        trimMode, IF(OR(mode = 1, mode = 2, mode = 3), mode, 1),
        // Trim functions
        trimStart, LAMBDA(s,
            REDUCE(
                s,
                SEQUENCE(LEN(s)),
                LAMBDA(a, _,
                    IF(
                        LEFT(a, 1) = charToTrim,
                        RIGHT(a, LEN(a) - 1),
                        a
                    )
                )
            )
        ),
        trimEnd, LAMBDA(s,
            REDUCE(
                s,
                SEQUENCE(LEN(s)),
                LAMBDA(a, _,
                    IF(
                        RIGHT(a, 1) = charToTrim,
                        LEFT(a, LEN(a) - 1),
                        a
                    )
                )
            )
        ),
        // Select a trim mode
        CHOOSE(
            trimMode,
            trimEnd(trimStart(str)),  // Mode 1: BOTH (default)
            trimStart(str),           // Mode 2: START only
            trimEnd(str)              // Mode 3: END only
        )
    )
)