The stackoverflow answer to "how to pretty print xml in java" in clojure

pretty_xml.clj

(ns pretty-xml
  (:import (java.io ByteArrayInputStream StringWriter)
           (javax.xml.parsers DocumentBuilderFactory)
           (javax.xml.transform TransformerFactory OutputKeys)
           (javax.xml.transform.dom DOMSource)
           (javax.xml.transform.stream StreamResult)
           (javax.xml.xpath XPathFactory XPathConstants)
           (org.w3c.dom Document NodeList Node)
           (org.xml.sax InputSource))

(defn nodes-seq [^NodeList nodes]
  (map #(.item nodes %) (range (.getLength nodes))))

;; https://stackoverflow.com/a/33541820/3680995
(defn pretty [^String s]
  (let [input (-> s .getBytes ByteArrayInputStream. InputSource.)
        doc (-> (DocumentBuilderFactory/newInstance)
                .newDocumentBuilder
                (.parse input)
                (doto .normalize))
        nodes (-> (XPathFactory/newInstance)
                  .newXPath
                  (.evaluate "//text()[normalize-space()='']"
                             doc
                             (XPathConstants/NODESET))
                  nodes-seq)

        transformer
        (doto (-> (TransformerFactory/newInstance) .newTransformer)
          (.setOutputProperty OutputKeys/ENCODING "UTF-8")
          (.setOutputProperty OutputKeys/INDENT "yes"))

        stringwriter (StringWriter.)]
    (run! #(doto (.getParentNode ^Node %) (.removeChild ^Node %)) nodes)
    (.transform transformer (DOMSource. doc) (StreamResult. stringwriter))
    (str stringwriter)))

(defn pprint [s]
  (println (pretty s)))