Created
February 22, 2017 07:48
-
-
Save mandarinx/00b7048ddd97db4d3ac9d5d6aafa7bb7 to your computer and use it in GitHub Desktop.
Shader for distoring, like heat waves
This file contains hidden or bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
// Per pixel bumped refraction. | |
// Uses a normal map to distort the image behind, and | |
// an additional texture to tint the color. | |
Shader "FX/Glass/Stained BumpDistort Orthographic" { | |
Properties { | |
_BumpAmt ("Distortion", range (0,128)) = 10 | |
_MainTex ("Tint Color (RGB)", 2D) = "white" {} | |
_BumpMap ("Normalmap", 2D) = "bump" {} | |
[Toggle(ORTHO)] _ORTHO("Orthographic", Float) = 0 | |
} | |
Category { | |
// We must be transparent, so other objects are drawn before this one. | |
Tags { "Queue"="Transparent" "RenderType"="Opaque" } | |
SubShader { | |
// This pass grabs the screen behind the object into a texture. | |
// We can access the result in the next pass as _GrabTexture | |
GrabPass { | |
Name "BASE" | |
Tags { "LightMode" = "Always" } | |
} | |
// Main pass: Take the texture grabbed above and use the bumpmap to perturb it | |
// on to the screen | |
Pass { | |
Name "BASE" | |
Tags { "LightMode" = "Always" } | |
CGPROGRAM | |
#pragma vertex vert | |
#pragma fragment frag | |
#pragma multi_compile_fog | |
#pragma shader_feature ORTHO | |
#include "UnityCG.cginc" | |
struct appdata_t { | |
float4 vertex : POSITION; | |
float2 texcoord: TEXCOORD0; | |
}; | |
struct v2f { | |
float4 vertex : SV_POSITION; | |
float4 uvgrab : TEXCOORD0; | |
float2 uvbump : TEXCOORD1; | |
float2 uvmain : TEXCOORD2; | |
UNITY_FOG_COORDS(3) | |
}; | |
float _BumpAmt; | |
float4 _BumpMap_ST; | |
float4 _MainTex_ST; | |
v2f vert (appdata_t v) | |
{ | |
v2f o; | |
o.vertex = mul(UNITY_MATRIX_MVP, v.vertex); | |
#if UNITY_UV_STARTS_AT_TOP | |
float scale = -1.0; | |
#else | |
float scale = 1.0; | |
#endif | |
o.uvgrab.xy = (float2(o.vertex.x, o.vertex.y*scale) + o.vertex.w) * 0.5; | |
o.uvgrab.zw = o.vertex.zw; | |
o.uvbump = TRANSFORM_TEX( v.texcoord, _BumpMap ); | |
o.uvmain = TRANSFORM_TEX( v.texcoord, _MainTex ); | |
UNITY_TRANSFER_FOG(o,o.vertex); | |
return o; | |
} | |
sampler2D _GrabTexture; | |
float4 _GrabTexture_TexelSize; | |
sampler2D _BumpMap; | |
sampler2D _MainTex; | |
half4 frag (v2f i) : SV_Target | |
{ | |
#if UNITY_SINGLE_PASS_STEREO | |
i.uvgrab.xy = TransformStereoScreenSpaceTex(i.uvgrab.xy, i.uvgrab.w); | |
#endif | |
// calculate perturbed coordinates | |
half2 bump = UnpackNormal(tex2D( _BumpMap, i.uvbump )).rg; // we could optimize this by just reading the x & y without reconstructing the Z | |
float2 offset = bump * _BumpAmt * _GrabTexture_TexelSize.xy; | |
#if ORTHO // for orthographic cameras` | |
i.uvgrab.xy = offset * (_BumpAmt * 0.3f) + i.uvgrab.xy; | |
#else // for perspective cameras | |
i.uvgrab.xy = offset * UNITY_Z_0_FAR_FROM_CLIPSPACE(i.uvgrab.z) + i.uvgrab.xy; | |
#endif | |
half4 col = tex2Dproj( _GrabTexture, UNITY_PROJ_COORD(i.uvgrab)); | |
half4 tint = tex2D(_MainTex, i.uvmain); | |
col *= tint; | |
UNITY_APPLY_FOG(i.fogCoord, col); | |
return col; | |
} | |
ENDCG | |
} | |
} | |
// ------------------------------------------------------------------ | |
// Fallback for older cards and Unity non-Pro | |
SubShader { | |
Blend DstColor Zero | |
Pass { | |
Name "BASE" | |
SetTexture [_MainTex] { combine texture } | |
} | |
} | |
} | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment