Ember Promised Properties

comment.coffee

# /app/controllers/comment.coffee
`import promisedProperty from "../utils/promised_property"`

CommentController = Ember.ObjectController.extend
  needs: ["application"]

  currentUser: Ember.computed.alias('controllers.application.currentUser')
  
  isCommentController: true

  currentCommentUser: promisedProperty(false, -> @get('model.user')
  ).property('model.user')

  isCurrentUser: (->
    @get('currentUser') == @get('currentCommentUser')
  ).property('currentUser', 'currentCommentUser')

  isActionsHidden: Ember.computed.alias('isCurrentUser')

  actions:
    saveTextField: (propertyName) ->
      @get('model').saveShadowedProperty(propertyName)

    deleteComment: ->
      @get('model').destroyRecord()

`export default CommentController;`

promised_property.coffee

# /app/utils/promised_property.coffee

# http://discuss.emberjs.com/t/promises-and-computed-properties/3333/10
promisedProperty = (initialValue, func) ->
  flightKey = '_promisedInFlight' + Ember.guidFor({})
  (k,v) ->
    return v if arguments.length > 1
    this[flightKey] ?= 0
    this[flightKey] += 1
    myNumber = this[flightKey]
    func.apply(this, [k,v]).then((result) =>
      if this[flightKey] <= myNumber
        @set(k, result)
      this[flightKey] -= 1
    )
    initialValue

`export default promisedProperty;`