shell.nix

{ buildStatic ? false }:
with import <nixpkgs> {};
let
  crystalLib = (import ./nix/crystal2nix.nix {
    inherit stdenv lib remarshal runCommand;
  }).crystalLib;
  staticStdenv = (makeStaticLibraries stdenv);
in mkShell {
  buildInputs = [
    postgresql100
    shards
    crystal
    libxml2
    libyaml
    openssl
    pkgconfig
    gmp
  ] ++ lib.optionals buildStatic [
    glibc.static
    zlib.static
    (openssl.override { stdenv = stdenv // {
      mkDerivation = args: stdenv.mkDerivation (args // {
        dontDisableStatic = true;
        configureFlags = [
          "no-shared"
          "--libdir=lib"
          "--openssldir=etc/ssl"
        ];
      });
    }; })
    (gmp.override      { stdenv = staticStdenv; })
    (libyaml.override  { stdenv = staticStdenv; })
    (libevent.override { stdenv = staticStdenv; })
    (pcre.override     { stdenv = staticStdenv; })
    (boehmgc.override  { stdenv = staticStdenv // { isLinux = false; }; })
  ];

  shellHook = ''
    rm -rf lib
    ln -s ${crystalLib} lib
    export PGDATA=$PWD/pg
  '';
}