Automator: opens the folder in a new iTerm2 window.

Open in new iTerm2 window

-- Adapted from these sources:
-- http://peterdowns.com/posts/open-iterm-finder-service.html
-- https://gist.github.com/cowboy/905546
-- https://gist.github.com/eric-hu/5846890

-- Modified to work with files as well, cd-ing to their container folder
-- Modified to do an ls -l if the selected item in Finder is a file so that you get the name of the file waiting for you in the terminal.
on run {input, parameters}
  tell application "Finder"
		set my_file to first item of input
		set filetype to (kind of (info for my_file))
		-- Treats OS X applications as files.  To treat them as folders, integrate this SO answer:
		-- http://stackoverflow.com/a/6881524/640517
		if filetype is "Folder" or filetype is "Volume" then
			set dir_path to quoted form of (POSIX path of my_file)
		else
			set dir_path to quoted form of (POSIX path of (container of my_file as string))
		end if
	end tell
	CD_to(dir_path, my_file)
end run

on CD_to(theDir, theFile)
	tell application "iTerm"
		activate
		set t to (make new terminal)
		tell t
			launch session "Default Session"
			tell the last session
				write text "cd " & theDir
				set filetype to (kind of (info for theFile))
				if filetype is not "Folder" and filetype is not "Volume" then
					write text "ls -l " & (POSIX path of theFile)	
				end if
			end tell
		end tell
	end tell
end CD_to