Cake file that watches coffee files and compiles them.

gistfile1.coffee

###
Compiles coffee scripts from coffee/ to js/.
###

fs = require 'fs'
{exec} = require 'child_process'
util = require 'util'
path = require 'path'

appFiles = []

task 'coffeeFiles', 'collect coffee files', ->
  traverseFileSystem = (currentPath) ->
    files = fs.readdirSync currentPath
    for file in files
      do (file) ->
        currentFile = currentPath + '/' + file
        stats = fs.statSync(currentFile)
        if stats.isFile() and currentFile.indexOf('.coffee') > 1 and currentFile not in appFiles
          appFiles.push currentFile
        else if stats.isDirectory()
          traverseFileSystem currentFile

  traverseFileSystem 'coffee'
  util.log "#{appFiles.length} coffee files found."
  return appFiles

task 'watch', 'watch coffee files and build changes', ->
  invoke 'coffeeFiles'
  util.log "watching for changes..."

  for file in appFiles then do (file) ->
    fs.watchFile file, (curr, prev) ->
      if +curr.mtime isnt +prev.mtime
        util.log "saw change in #{file}"
        outputPath = path.dirname(file).replace /coffee/, "js"
        exec "coffee -cwo #{outputPath} #{file}"