PKGBUILD for texi2latex

PKGBUILD

# Maintainer: Mario Rodas <rodasmario2@gmail.com>

pkgname=texi2latex
pkgver=0.9.4
pkgrel=2
pkgdesc="convert texinfo sources to LaTeX"
url="http://savannah.nongnu.org/projects/texi2latex"
arch=('i686' 'x86_64')
license=('GPL')
depends=('gcc-libs' 'sh' 'java-saxon')
source=("http://mirrors.zerg.biz/nongnu/$pkgname/$pkgname-$pkgver.tar.bz2")
md5sums=('73285a6f0bb988a6673b445a71bf94fd')


build() {
  cd $srcdir/$pkgname-$pkgver

  make ROOT= USRDIR=/usr tbrplent texi2latex
}

package() {
  cd $srcdir/$pkgname-$pkgver

  # Dont use `make install' because is fucked
  install -d "$pkgdir/usr/bin"
  install -d "$pkgdir/usr/share/xml/tbook"
  install -d "$pkgdir/usr/share/xml/texi2latex"
  install -d "$pkgdir/usr/share/texmf/makeindex"

  install -m755 "texi2latex" "$pkgdir/usr/bin"
  install -m644 "texi2latex.ist" "$pkgdir/usr/share/texmf/makeindex"
  install -m755 "tbrplent/tbrplent" "$pkgdir/usr/bin"
  install -m644 "tbrplent/tbents.txt" "$pkgdir/usr/share/xml/tbook"
  install -m644 xslt/*.xsl xslt/*.xml xslt/texinfo.dtd "$pkgdir/usr/share/xml/texi2latex"
}