ats-anairiats-svn PKGBUILD

PKGBUILD

# Maintainer: Mario Rodas <[email protected]>

pkgname=ats-anairiats-svn
_svnname=ats-anairiats
pkgver=r3461
pkgrel=1
pkgdesc="Statically typed programming language"
url="http://www.ats-lang.org"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('gmp')
options=('staticlibs' '!emptydirs')
makedepends=('subversion')
optdepends=()
conflicts=()
provides=()

# https://github.com/githwxi/ATS-Postiats/wiki/ATS-implementations#atsanairiats
source=("${_svnname}::svn+https://svn.code.sf.net/p/ats-lang/code/trunk"
        'bootstrap0::svn+https://svn.code.sf.net/p/ats-lang/code/bootstrap/anairiats/')

md5sums=('SKIP'
         'SKIP')

# XXX: PACKAGE_VERSION in ats-anairiats/config.mk
_version=0.2.11

pkgver() {
  cd "$srcdir/$_svnname"
  local ver="$(svnversion)"
  printf "r%s" "${ver//[[:alpha:]]}"
}

prepare(){
  cp -a "$srcdir/bootstrap0" "$srcdir/$_svnname/bootstrap0"
}

build() {
  cd "$srcdir/$_svnname"
  make configure
  ./configure --prefix="/usr"
  make all
  make contrib
}

# check() {
#   cd "$srcdir/$_svnname"
#   make test
# }

# XXX: ATSNEWHOME is hardcoded based on the wrapper scripts.
package() {
  cd "$srcdir/$_svnname"
  make DESTDIR="$pkgdir" ATSNEWHOME="/usr/lib/$_svnname-$_version" install
  cp -av utils "$pkgdir/usr/lib/$_svnname-$_version/"
  cp -av libatsdoc "$pkgdir/usr/lib/$_svnname-$_version/"
}