Comonad on a Kleisli category

ComonadKleisli.hs

module ComonadKleisli where

import Data.Maybe
import Data.List
import Control.Monad

fmapM :: (a -> Maybe b) -> [a] -> Maybe [b]
fmapM f = Just . catMaybes . fmap f

duplicateM :: [a] -> Maybe [[a]]
duplicateM = pure . tails

extractM :: [a] -> Maybe a
extractM = listToMaybe

-- Comonad laws:
-- - extractM <=< duplicateM       = pure
-- - fmapM extractM <=< duplicateM = pure
-- - duplicateM <=< duplicateM     = fmapM duplicateM <=< duplicateM

extendM :: ([a] -> Maybe b) -> [a] -> Maybe [b]
extendM f = fmapM f <=< duplicateM

isHeader :: String -> Bool
isHeader ('#' : _) = True
isHeader _         = False

test :: [String] -> Maybe [[String]]
test = extendM $ \l -> do
 (h, xs) <- uncons l
 if isHeader h
   then Just $ h : takeWhile (not . isHeader) xs
   else Nothing

main :: IO ()
main = do
 print $ test ["# header", "text", "more text", "# header 2", "some text"]
 -- Just [["# header","text","more text"],["# header 2","some text"]]
 print $ test []
 -- Just []
 print $ test ["foo", "bar", "# header", "baz"]
 -- Just [["# header","baz"]]