Advent of code 2017 day 1 part 1 in Brainfuck

aoc_2017_1_1.bf

must be run on cell size of 16 bits or more with wrapping on inc and dec operations

>>
,[------------------------------------------------>,] read input and convert ascii digits to data

copy the first digit to the end (to handle wrapping)
  + add 1 to the end space to mark it 
  
  [<]> goto first digit 
  [<+[>]<+[<]>>-] move to marked space and the space before first digit <[>+<-] >[>]<
  - subtract the 1 we added

we are now on the rightmost digit (the one we just copied)
we want to loop through each digit and if it is equal one to its left, add it to the total
the memory looks like this
result 0 first second third _______ last firstcopy
(by the way I use * as a plus sign and ~ as a minus sign)

[       while digit is nonzero (we rely on the fact that none of the digits in the input are 0)
  <
  r 0 ___(a) b t1 t2
  [->>+>+<<<]  >> [-<<+>>]  copy a to t2
  t1
  <
  r 0 ___a (b) 0 a

  instead of adding b if the numbers are equal we always add b and then subtract when they are not equal
  [>>>+<<< [<]<+ >>[>]>-<<-]
  r*b 0 ___a (0) 0 a~b b 

  >>>[<<<+>>>-]
  r*b 0 ___a b 0 a~b (0)
  <
  r*b 0 ___a b 0 (a~b) 0
  if a~b is nonzero we subtract b from the result
  [
    <<
    r*b 0 ___a (b) 0 a~b 0
    [
      [<]
      r*b (0) ___a b 0 a~b 0
      <-
      (r*b~) 0 ___a b 0 a~b 0
      >>[>]
      r*b~ 0 ___a b (0) a~b 0
      <-
      r*b~ 0 ___a b~ 0 a~b 0
    ]
    r 0 ___a (0) 0 a~b 0

    >>[-]
    r 0 ___a 0 0 (0) 0
  ]
  r*?b 0 ___a b? 0 (0) 0 
  b will be added to r iff a was equal to b
  if it was equal and we skipped that if block then we never deleted b and should zero it out now
  <<[-]
  r*?b 0 ___a (0) 0 0 0

  move to the next digit in line
  <
]
r (0)

<
(r)

print result as ascii
[>>+>+<<<-]>>>[<<<+>>>-]<<+>[<->[>++++++++++<[->-[>+>>]>[+[-<+>]>+>>]<<<<<]>[-]
  ++++++++[<++++++>-]>[<<+>>-]>[<<+>>-]<<]>]<[->>++++++++[<++++++>-]]<[.[-]<]<

You monster.