DistinctListSort

DistinctListSort.txt

/** DistinctListSort */
/*
    FUNCTION NAME: DistinctListSort
    DESCRIPTION: Given a n-row by 1-column range of concatenated text,
        returns a n-row by 1-column array of the unique values. Return
        array is sorted
    ARGS:
        rng: Range holding original values
        delim: Delimiter used to split the concatenated strings
        col: Column index you want returned (1st column = 1)
        sortorder: 1 for ascending, -1 for descending

    EXAMPLE: 
        =DistinctListSort(A1:A1000,"|",4,1)
*/
DistinctListSort = LAMBDA(
    rng,
    delim,
    col,
    sortorder,
    SORT(
        UNIQUE(
            BYROW(
                rng, 
                LAMBDA(
                    r, 
                    INDEX(
                        TEXTSPLIT(
                            r, 
                            delim
                        ), 
                        col
                    )
                )
            )
        ),
        ,
        sortorder
    )
)