Google Analytics Event Tracking w/Callbacks & Timeout

gistfile1.coffee

# A simple "once" implementation. Can be replaced with _.once or similar.
once = (func) ->
  ran = false
  ->
    return if ran
    ran = true
    func.apply this, arguments
    func = null
    undefined

# A simple "extend" implementation. Can be replaced with $.extend or similar.
extend = (target, sources...) ->
  for source in sources
    for own k, v of source
        target[k] = v
  target

# Logs an event, then executes a callback. If the tracking call hasn't completed
# after `timeout` ms, the errback is called.
#
# The following example calls submit form whether tracking was successful or
# not:
#
#     gaTrackEvent(['send', 'event', 'category', 'action'], {page: '/my-new-page'}, submitForm, submitForm);
gaTrackEvent = (gaArgs, gaOpts, callback, errback, timeout = 1000) ->
  done = once (error, args) ->
    if error
      errback args...
    else
      callback args...

  newOpts = extend {}, gaOpts or {}
  newOpts.hitCallback = (args...) ->
    gaOpts?.hitCallback? args...
    done false, args

  ga gaArgs..., newOpts
  setTimeout (-> done true), timeout