index.coffee

# "affix" and "scrollspy", before bootstrap had them:
$ ->
  $nav = $('nav')
  navTop = $nav.offset?().top - 12
  navFixed = 0
  sections = {}
  for section in $('section')
    $section = $(section)
    id = $section.attr('id')
    if id
      offset = $section.offset()
      sections[id] = offset.top + offset.height

  setNavPos = (scrollPos) ->
    if scrollPos >= navTop and navFixed is 0
      $nav.addClass('nav-fixed')
      $nav.css({width: $nav.parent().width()})
      navFixed = 1
    else if scrollPos <= navTop and navFixed is 1
      $nav.removeClass('nav-fixed')
      $nav.css({width: undefined})
      navFixed = 0

  setCurrentSection = (scrollPos) ->
    current = ((section) for section, offset of sections when scrollPos - offset < 0)[0]
    $nav.find("li").removeClass('active')
    $nav.find("li > a[href=##{current}]").parent().addClass('active')

  $win.resize ->
    navFixed = -1
    setNavPos($win.scrollTop())

  $win.scroll ->
    scrollPos = $win.scrollTop()
    setNavPos(scrollPos)
    setCurrentSection(scrollPos)

  $nav.delegate 'li > a', 'click', (event) ->
    event.preventDefault()
    $dest = $($(this).attr('href'))
    $win.scrollTop($dest.offset()?.top)