Run config for spongevanilla

build.gradle

plugins {
    id 'java-library'
}

repositories {
    jcenter()
    maven {
        name = "SpongeMaven"
        url = "https://repo.spongepowered.org/maven"
    }
}
configurations {
    runtime {
        exclude group: 'org.spongepowered', module: 'spongeapi'
    }
    server {
        transitive = false
    }
}
dependencies {
    api 'org.spongepowered:spongeapi:7.2.0'
    server 'org.spongepowered:spongevanilla:1.12.2-7.2.4-RC375'
}

task runServer(type: JavaExec) {

    // the run directory
    workingDir 'run'
    // scan the full classpath for plugin dependencies
    // can be changed to --scan-classpath if there are no plugin dependencies
    args += ['--scan-full-classpath']
    // memory and other jvm args
    jvmArgs += ['-Xmx2g', '-Xms2g']

    // required for starting the server
    classpath = configurations.server + sourceSets.main.runtimeClasspath
    main = 'org.spongepowered.server.launch.VanillaServerMain'
    standardInput = System.in

    doFirst {
        // makes sure the run directory exists
        workingDir.mkdirs()
    }
}