Mozilla extension user-agent rewriting extension example rewritten in purescript

packages.dhall

let upstream =
      https://github.com/purescript/package-sets/releases/download/psc-0.13.6-20200123/packages.dhall sha256:687bb9a2d38f2026a89772c47390d02939340b01e31aaa22de9247eadd64af05

let overrides = {=}

let additions =
  { web-extensions =
      { dependencies =
        [ "aff"
        , "aff-promise"
        , "console"
        , "effect"
        , "foreign"
        , "nullable"
        , "options"
        , "prelude"
        , "promises"
        ]
      , repo =
          "https://gitlab.com/d86leader/purescript-web-extensions.git"
      , version =
          "9b89b90f5740f278949286df3a41334a69496ec1"
      }
  }

in  upstream // overrides // additions

RewriteUa.purs

-- | A purescript rewrite of this example extension:
-- | https://github.com/mdn/webextensions-examples/tree/master/user-agent-rewriter
module RewriteUa (main) where

import Prelude
import Browser.Event (addListener)
import Data.Options ((:=))
import Data.String.Common (toLower)
import Effect (Effect)
import Browser.WebRequest
    ( onBeforeSendHeadersBlocking, OnBeforeSendHeadersDetails (..)
    , requestFilter, requestHeaders
    )

import Effect.Console as Console

main :: Effect Unit
main = Console.log "main running!" *>
    let filter = requestFilter [targetPage] mempty
        targetPage = "https://httpbin.org/*"
    in addListener onBeforeSendHeadersBlocking filter $
        \(OnBeforeSendHeadersDetails details) -> do
           let headers = details.requestHeaders
           let headers' = map changeUa headers
           Console.log "overwritten headers"
           pure $ requestHeaders := headers'
    where
        changeUa header =
            if toLower header.name == "user-agent"
            then header {value = "curl/7.60.0"}
            else header

spago.dhall

{ name = "rewrite-ua"
, dependencies =
  [ "effect"
  , "web-extensions"
  ]
, packages = ./packages.dhall
, sources = [ "RewriteUa.purs" ]
}