Chlorine Config for custom resolver of goto var definition

chlorine-config.cljs

(defn- get-resolver-for-keyword [k]
  (p/let [{:keys [text]} (editor/get-namespace)
          namespace (str/replace text #"(.*?\.).*" "$1")
          res (editor/run-feature :eql [{(list :repl/namespaces {:filter namespace})
                                         [:repl/namespace {:namespace/vars [:var/fqn]}]}])
          vars (for [{:namespace/keys [vars]} (:repl/namespaces res)
                     {:var/keys [fqn]} vars]
                 fqn)
          code (str "(->> " (vec vars)
                    "     (filter (fn [r] (-> r :com.wsscode.pathom.connect/output set (contains? " k "))))"
                    "     (map #(select-keys % [:com.wsscode.pathom.connect/sym :com.wsscode.pathom.connect/output]))"
                    "     first)")
          {:keys [result]} (editor/eval {:text code :auto-detect true})]
    result))

(editor/add-resolver
 {:inputs [:editor/current-var]
  :outputs [:definition/info :definition/line]}
 (fn [{:editor/keys [current-var]}]
   (when (str/starts-with? current-var ":")
     (p/catch
      (p/let [result (get-resolver-for-keyword current-var)
              sym (:com.wsscode.pathom.connect/sym result)
              info (editor/eql {:var/fqn sym :editor/current-var ""}
                               [:definition/info :definition/line])]
        (when (:definition/info info)
          info))
      log))))

This is the result: