Monads with Clojure

monads.clj

(ns monads)

(defn- ensure-instance [class val constructor]
  (if (instance? class val)
    val
    (constructor val)))

(defprotocol IMonad
  (bind [this f]))

; Maybe Monad
(defrecord Just [val]
  IMonad
  (bind [_ f] (ensure-instance Just (f val) ->Just)))
(defrecord Nothing []
  IMonad
  (bind [this _] this)) 

; Try Monad
(defrecord Failure [e]
  IMonad
  (bind [this _] this)) 

(defrecord Success [val]
  IMonad
  (bind [_ f] (try
                (ensure-instance Success (f val) ->Success)
                (catch Exception e (Failure. e)))))

; You can run monads with the following:
(bind (Success. 10) #(/ % 0))

; But, when one monad depends on the other, this could
; become VERY confusing:
(bind (Just. 10) (fn [ten]
                   (bind (Just. 11) (fn [eleven]
                                      (+ ten eleven)))))
                                    

; we can work-arount this with some helper macro:
(defn- for-aux [[[bind var] & rest] fns]
  (if bind
    `(bind ~var (fn [~bind] 
                  ~(for-aux rest fns)))
    fns))

(defmacro for-monad [binds body]
  (assert (even? (count binds)) "Binds must be even")
  (for-aux (partition 2 binds) body))

; It works like this:
; (NOTE: This is equivalent to Scala's code
; for {
;   ten <- Some(10)
;   eleven <- Some(11)
; } yield ten + eleven
(for-monad [ten (Just. 10)
            eleven (Just. 11)]
  (+ ten eleven))