Part1.fs

let ones =
    seq {
        while true do
            yield 1
    }
// seq [1; 1; 1; 1; ...]

Part2.fs

// Can't do this, unfortunately
// seq { 1 .. }
//
// or this:
// seq { 1 .. 0 .. 2 }
//
// Which I thought might be a nice hack.

Part3.fs

let notInfiniteOrOnes = seq { 1 .. System.Int32.MaxValue }
// seq [1; 2; 3; 4; ...]

let notInfinite = seq { for _ in 1 .. System.Int32.MaxValue -> 1 }
// seq [1; 1; 1; 1; ...]

Part4.fs

let ones' =
    let rec gen () =
        seq {
            yield 1
            yield! gen ()
        }
    gen ()
// seq [1; 1; 1; 1; ...]

Part5.fs

let ones'' = Seq.initInfinite (fun _ -> 1)
// seq [1; 1; 1; 1; ...]

Part6.fs

let ones''' = Seq.unfold (fun _ -> Some (1, ())) ()
// seq [1; 1; 1; 1; ...]

Part7.fs

let moreInterestingUnfold =
    Seq.unfold
        (fun state ->
            Some (state, state + 1)) 1
// seq [1; 2; 3; 4; ...]

Part8.fs

type Time =
    {
        Hour : int
        Minute : int
    }

let addMinute time =
    match time with
    | { Hour = 23; Minute = 59 } ->
        { Hour = 0; Minute = 0 }
    | { Minute = 59 } ->
        { Hour = time.Hour + 1; Minute = 0 }
    | _ ->
        { Hour = time.Hour; Minute = time.Minute + 1 }

let unfold' =
    Seq.unfold
        (fun state ->
            Some (sprintf "%02d:%02d" state.Hour state.Minute, addMinute state)
            ) { Hour = 22; Minute = 59 }
// seq ["23:59"; "00:00"; "00:01"; "00:02"; ...]