Run a Python script in a conda environment from a batch file

run_python_script_in_conda_env.bat

@echo OFF
rem How to run a Python script in a given conda environment from a batch file.

rem It doesn't require:
rem - conda to be in the PATH
rem - cmd.exe to be initialized with conda init

rem Define here the path to your conda installation
set CONDAPATH=C:\ProgramData\Miniconda3
rem Define here the name of the environment
set ENVNAME=someenv

rem The following command activates the base environment.
rem call C:\ProgramData\Miniconda3\Scripts\activate.bat C:\ProgramData\Miniconda3
if %ENVNAME%==base (set ENVPATH=%CONDAPATH%) else (set ENVPATH=%CONDAPATH%\envs\%ENVNAME%)

rem Activate the conda environment
rem Using call is required here, see: https://stackoverflow.com/questions/24678144/conda-environments-and-bat-files
call %CONDAPATH%\Scripts\activate.bat %ENVPATH%

rem Run a python script in that environment
python script.py

rem Deactivate the environment
call conda deactivate

rem If conda is directly available from the command line then the following code works.
rem call activate someenv
rem python script.py
rem conda deactivate

rem One could also use the conda run command
rem conda run -n someenv python script.py

Saved me so much trouble shooting! Thank you!

Thanks for sharing!!! this save me lot of issues.

Thanks. The "call" part is what I was missing. Appreciate it!

Thanks for this, for some strange reason I had to change this line:
call %CONDAPATH%\Scripts\activate.bat %ENVPATH%

to:
call %CONDAPATH%\Scripts\activate.bat %ENVNAME%

Thanks!

I add my thanks! I look all over before stumbling across this!
I spent some time comparing the environment variables after each line of your batch file and they were essentially identical as those produced when interactively using the "Anaconda Prompt" that is installed with anaconda3. (i.e., Click on the Prompt icon, then "conda activate ") Only exceptions (obviously) were the three envvars created (set) within your batch file. I did not try out/verify your greyed-out alternatives.

My only complaint is that it takes forever (about 3 sec) for my Python script to start executing. But when I used a stopwatch on the combined time for the two interactive steps, this was also about 3 sec. I read elsewhere that conda is slow coming up, so, I suspect this, rather than the specifics of my Python script, is the problem.