spl-module_0.6.5.6.bb

SUMMARY = "The Solaris Porting Layer is a Linux kernel module which provides many of the Solaris kernel APIs"
LICENSE = "GPLv2"
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"

SRC_URI = "http://archive.zfsonlinux.org/downloads/zfsonlinux/spl/spl-0.6.5.6.tar.gz"
SRC_URI[md5sum] = "4544b80018ddc5c39ed395363a582228"
SRC_URI[sha256sum] = "167595fe76eb5497c3a1ffe396b6300155d0cbe46d06824a710099ca1ae1b8bd"

S = "${WORKDIR}/spl-${PV}"

inherit module autotools

EXTRA_OECONF = " --with-config=kernel --with-linux=${STAGING_KERNEL_DIR} --with-linux-obj=${STAGING_KERNEL_BUILDDIR}"

FILES_${PN}-dev = " \
  /usr/src/spl-${PV} \
"
sysroot_stage_all_append () {
  sysroot_stage_dir ${D}/usr/src/spl-${PV} ${SYSROOT_DESTDIR}/usr/src/spl-${PV}
}

zfs-module_0.6.5.6.bb

SUMMARY = "Native OpenZFS filesystem kernel modules for Linux"
LICENSE = "CDDL-1.0"
LIC_FILES_CHKSUM = "file://OPENSOLARIS.LICENSE;md5=7087caaf1dc8a2856585619f4a787faa"

SRC_URI = "http://archive.zfsonlinux.org/downloads/zfsonlinux/zfs/zfs-0.6.5.6.tar.gz"
SRC_URI[md5sum] = "8c05b3cfcb0c25b1469032404ec032fe"
SRC_URI[sha256sum] = "c349d46d86b4f61cd53a0891acad916cfc3f0d6754127db7f60a0bd98185aeff"

S = "${WORKDIR}/zfs-${PV}"

inherit module autotools

DEPENDS = "spl-module"

EXTRA_OECONF = " \
  --with-config=kernel --with-linux=${STAGING_KERNEL_DIR} --with-linux-obj=${STAGING_KERNEL_BUILDDIR} \
  --with-spl=${STAGING_DIR_HOST}/usr/src/spl-${PV} \
"

FILES_${PN}-dev = " \
  /usr/src/zfs-${PV} \
"

zfs_0.6.5.6.bb

SUMMARY = "Native OpenZFS filesystem userland tools for Linux"
LICENSE = "CDDL-1.0"
LIC_FILES_CHKSUM = "file://OPENSOLARIS.LICENSE;md5=7087caaf1dc8a2856585619f4a787faa"

SRC_URI = "http://archive.zfsonlinux.org/downloads/zfsonlinux/zfs/zfs-0.6.5.6.tar.gz"
SRC_URI[md5sum] = "8c05b3cfcb0c25b1469032404ec032fe"
SRC_URI[sha256sum] = "c349d46d86b4f61cd53a0891acad916cfc3f0d6754127db7f60a0bd98185aeff"

inherit autotools systemd

DEPENDS = "spl-module zfs-module"
RDEPENDS_${PN} = "python bash"

EXTRA_OECONF = " \
    --with-config=user --with-linux=${STAGING_KERNEL_DIR} --with-linux-obj=${STAGING_KERNEL_BUILDDIR} \
    --with-spl=${STAGING_DIR_HOST}/usr/src/spl-${PV} \
    --without-blkid \
"

PACKAGECONFIG ??= " \
    ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)} \
"

PACKAGECONFIG[systemd] = "--enable-systemd --with-systemdunitdir=${systemd_system_unitdir} --with-systemdpresetdir=${systemd_unitdir}/system-preset,--disable-systemd,systemd"

PACKAGES =+ "${PN}-zed ${PN}-zfs-import-cache ${PN}-zfs-import-scan ${PN}-zfs-mount ${PN}-zfs-share"

SYSTEMD_PACKAGES = "${PN} ${PN}-zed ${PN}-zfs-import-cache ${PN}-zfs-import-scan ${PN}-zfs-mount ${PN}-zfs-share"
SYSTEMD_SERVICE_${PN} = "zfs.target"
SYSTEMD_SERVICE_${PN}-zed = "zed.service"
SYSTEMD_SERVICE_${PN}-zfs-import-cache = "zfs-import-cache.service"
SYSTEMD_SERVICE_${PN}-zfs-import-scan = "zfs-import-scan.service"
SYSTEMD_SERVICE_${PN}-zfs-mount = "zfs-mount.service"
SYSTEMD_SERVICE_${PN}-zfs-share = "zfs-share.service"

FILES_${PN} = " \
    /sbin \
    /bin \
    /etc/zfs \
    /etc/default \ 
    /usr/lib \
    /usr/sbin \
    /usr/bin \
    /usr/share/zfs \
    /usr/share/initramfs-tools \
    /lib/udev/vdev_id \
    /lib/udev/zvol_id \
    /lib/udev/rules.d \
    /lib/systemd/system-preset \
"

FILES_${PN}-dbg += " \
  /lib/udev/.debug \
"