Error with linking Mercury with a static file

Makefile

minimal_fails: minimal_fails.m
	mmc --make -v -l:libRmath.a -L `pkg-config --variable=libdir libRmath` minimal_fails && ./minimal_fails

minimal_ok: minimal_ok.m
	mmc --make -v -l:libRmath.a -L `pkg-config --variable=libdir libRmath` minimal_ok && ./minimal_ok

minimal_fixed: minimal_fixed.m
	mmc --make -v -l:libRmath.a -L `pkg-config --variable=libdir libRmath` minimal_fixed && ./minimal_fixed

minimal_fails.m

:- module minimal_fails.

:- interface.
:- import_module float, io.
:- func dwilcox(float,float,float,int) = float.
:- func pnorm(float,float,float,int,int) = float.
:- pred main(io::di, io::uo) is det.

:- implementation.

:- pragma foreign_proc("C",
    dwilcox(P::in,M::in,N::in,Log::in) = (Dwilcox_::out),
    [promise_pure, will_not_call_mercury],
    "Dwilcox_ = dwilcox(P,M,N,Log);").
:- pragma foreign_proc("C",
    pnorm(Q::in,Mean::in,Sd::in,Lower::in,Log::in) = (Pnorm_::out),
    [promise_pure, will_not_call_mercury],
    "Pnorm_ = pnorm(Q,Mean,Sd,Lower,Log);").

:- pragma foreign_decl("C", "
#define MATHLIB_STANDALONE
#include \"Rmath.h\"
typedef unsigned int Int32;
").

:- pragma foreign_code("C", 
"void set_seed(Int32 inseed, Int32 ignored) { }
double unif_rand(void) { return 0.5; }
").

main(!IO) :-
    P = pnorm(1.96, 0.0, 1.0, 1, 0),
    print_line(P, !IO).

minimal_fixed.m

:- module minimal_fixed.

:- interface.
:- import_module float, io.
:- func dwilcox(float,float,float,int) = float.
:- func pnorm(float,float,float,int,int) = float.
:- pred main(io::di, io::uo) is det.

:- implementation.

:- pragma foreign_proc("C",
    dwilcox(P::in,M::in,N::in,Log::in) = (Dwilcox_::out),
    [promise_pure, will_not_call_mercury],
    "Dwilcox_ = dwilcox(P,M,N,Log);").
:- pragma foreign_proc("C",
    pnorm(Q::in,Mean::in,Sd::in,Lower::in,Log::in) = (Pnorm_::out),
    [promise_pure, will_not_call_mercury],
    "Pnorm_ = pnorm(Q,Mean,Sd,Lower,Log);").

:- pragma foreign_decl("C", "
#define MATHLIB_STANDALONE
#include \"Rmath.h\"
#include <math.h>
#include <stdint.h>
typedef unsigned int Int32;
").

:- pragma foreign_code("C", 
"void set_seed(Int32 inseed, Int32 ignored) { }
double unif_rand(void) { return 0.5; }
//copied from src/nmath/standalone/sunif.c:
//generate a random non-negative integer < 2 ^ bits in 16 bit chunks
static double rbits(int bits)
{
    int_least64_t v = 0;
    for (int n = 0; n <= bits; n += 16) {
        int v1 = (int) floor(unif_rand() * 65536);
        v = 65536 * v + v1;
    }
    // mask out the bits in the result that are not needed
    return (double) (v & ((1L << bits) - 1));
}
double R_unif_index(double dn)
{
    // rejection sampling from integers below the next larger power of two
    if (dn <= 0)
        return 0.0;
    int bits = (int) ceil(log2(dn));
    double dv;
    do { dv = rbits(bits); } while (dn <= dv);
    return dv;
}

").

main(!IO) :-
    P = pnorm(1.96, 0.0, 1.0, 1, 0),
    print_line(P, !IO).

minimal_ok.m

:- module minimal_ok.

:- interface.
:- import_module float, io.
:- func pnorm(float,float,float,int,int) = float.
:- pred main(io::di, io::uo) is det.

:- implementation.

:- func dwilcox(float,float,float,int) = float. %% THIS HAS MOVED FROM THE INTERFACE

:- pragma foreign_proc("C",
    dwilcox(P::in,M::in,N::in,Log::in) = (Dwilcox_::out),
    [promise_pure, will_not_call_mercury],
    "Dwilcox_ = dwilcox(P,M,N,Log);").
:- pragma foreign_proc("C",
    pnorm(Q::in,Mean::in,Sd::in,Lower::in,Log::in) = (Pnorm_::out),
    [promise_pure, will_not_call_mercury],
    "Pnorm_ = pnorm(Q,Mean,Sd,Lower,Log);").

:- pragma foreign_decl("C", "
#define MATHLIB_STANDALONE
#include \"Rmath.h\"
typedef unsigned int Int32;
").

:- pragma foreign_code("C", 
"void set_seed(Int32 inseed, Int32 ignored) { }
double unif_rand(void) { return 0.5; }
").

main(!IO) :-
    P = pnorm(1.96, 0.0, 1.0, 1, 0), %% expects approximately 1-0.05/2.0=0.975
    print_line(P, !IO).

I have now added minimal_fixed.m, which fixes the issue with [dpqr]wilcox. In outline, rwilcox() calls R_rand_index() -- which needs to be re-defined for a user-defined random number generator. I have passed this information back to the R-devel mailing list.