Spring Jackson JSON serializer for Groovy GStrings

GStringJsonSerializer.groovy

import com.fasterxml.jackson.core.JsonGenerator
import com.fasterxml.jackson.core.JsonProcessingException
import com.fasterxml.jackson.databind.ObjectMapper
import com.fasterxml.jackson.databind.SerializerProvider
import com.fasterxml.jackson.databind.module.SimpleModule
import com.fasterxml.jackson.databind.ser.std.StdSerializer
import org.springframework.beans.factory.annotation.Autowired
import org.springframework.stereotype.Component

@Component
class GStringJsonSerializer extends StdSerializer<GString> {

  @Autowired
  GStringJsonSerializer(ObjectMapper objectMapper) {
    super(GString)

    def module = new SimpleModule()
    module.addSerializer(GString, this)
    objectMapper.registerModule(module)
  }

  @Override
  void serialize(GString value, JsonGenerator gen, SerializerProvider serializers)
      throws IOException, JsonProcessingException {
    gen.writeString(value.toString())
  }

}

Drop this class into your Spring project to create a self-registering JsonSerializer bean which teaches Jackson to serialize Groovy GStrings. This way, if a RestController returns an object with a GString in it, it'll give you something rational like:

{
  "message": "Hello, world"
}

instead of the nonsense it would otherwise come up with:

{
  "message": {
    "strings": ["Hello, ", ""],
    "values": ["world"],
    "bytes":"SGVsbG8sIHdvcmxk",
    "valueCount":1
  }
}

Doing the same for XML serialization is left as an exercise for the reader, if you're into that sort of thing.