Toggle expand bottom panel from plugin (hacky)

plugin.gd

tool
extends EditorPlugin


func _enter_tree():
	var base = get_editor_interface().get_base_control()
	var expand_button:ToolButton = get_expand_bottom_panel_button(base)
	expand_button.pressed =  not expand_button.pressed




# =========================== utils ==========================


static func get_node_by_class_path(node:Node, class_path:Array)->Node:
	var res:Node

	var stack = []
	var depths = []

	var first = class_path[0]
	for c in node.get_children():
		if c.get_class() == first:
			stack.push_back(c)
			depths.push_back(0)

	if not stack: return res
	
	var max_ = class_path.size()-1

	while stack:
		var d = depths.pop_back()
		var n = stack.pop_back()

		if d>max_:
			continue
		if n.get_class() == class_path[d]:
			if d == max_:
				res = n
				return res

			for c in n.get_children():
				stack.push_back(c)
				depths.push_back(d+1)

	return res



static func get_expand_bottom_panel_button(base:Control)->Button:
	var result: Button = get_node_by_class_path(
		base, [
			'VBoxContainer', 
			'HSplitContainer',
			'HSplitContainer',
			'HSplitContainer',
			'VBoxContainer',
			'VSplitContainer',
			'PanelContainer',
			'VBoxContainer',
			'HBoxContainer',
			'ToolButton'
		]
	)
	return result