DelegatesTo any type in Groovy 2.4+

ratpack-delegation.groovy

trait Configurable<ConfigObject> {
    ConfigObject configObject

    void configure(Closure<Void> configSpec) {
        configSpec.resolveStrategy = Closure.DELEGATE_FIRST
        configSpec.delegate = configObject
        configSpec()
    }
}
public <T,U extends Configurable<T>> U configure(Class<U> clazz, @DelegatesTo(type="T") Closure configSpec) {
    Configurable<T> obj = (Configurable<T>) clazz.newInstance()
    obj.configure(configSpec)
    obj
}
class Module implements Configurable<ModuleConfig> {
    String value

    Module(){
        configObject = new ModuleConfig()
    }

    @Override
    void configure(Closure<Void> configSpec) {
        Configurable.super.configure(configSpec)
        value = "${configObject.name}-${configObject.version}"
    }
}
class ModuleConfig {
    String name
    String version
}
@CompileStatic
void doTest() {
    def module = configure(Module) {
        name = 'test'
        version = '1.0'
    }
    assert module.value == 'test-1.0'
}