Losslessly splits an input Quicktime .mov file into 5-minute chunks. -- Requires the "splitmovie" utility, from the QT_Coffee Quicktime utilities package: http://www.3am.pair.com/QTCoffee.html

qtSplitter.applescript

-- This AppleScript will losslessly split an input Quicktime .mov file into 5-minute chunks.
-- Requires the "splitmovie" utility, from the QT_Coffee Quicktime utilities package: http://www.3am.pair.com/QTCoffee.html
--
-- Usage: Save this script as an Application, and drop the source QT files onto the .app to begin the splitting process.
-- Note: There is currently no visual feedback that the script is processing the file. I'm too lazy to add this at the moment.


property type_list : {"MOV"}
property extension_list : {"mov"}

-- This droplet processes both files or folders of files dropped onto the applet
on open these_items
	repeat with i from 1 to the count of these_items
		set this_item to (item i of these_items)
		set the item_info to info for this_item
		if folder of the item_info is true then
			process_folder(this_item)
		else if (alias of the item_info is false) and ¬
			((the file type of the item_info is in the type_list) or ¬
				the name extension of the item_info is in the extension_list) then
			process_item(this_item)
		end if
	end repeat
end open

-- this sub-routine processes folders
on process_folder(this_folder)
	set these_items to list folder this_folder without invisibles
	repeat with i from 1 to the count of these_items
		set this_item to alias ((this_folder as text) & (item i of these_items))
		set the item_info to info for this_item
		if folder of the item_info is true then
			process_folder(this_item)
		else if (alias of the item_info is false) and ¬
			((the file type of the item_info is in the type_list) or ¬
				the name extension of the item_info is in the extension_list) then
			process_item(this_item)
		end if
	end repeat
end process_folder

-- this sub-routine processes files
on process_item(this_item)
	-- NOTE that the variable this_item is a file reference in alias format
	do shell script ("/usr/local/bin/splitmovie -o '" & (POSIX path of this_item) & "_split.mov' -self-contained -no-fast-start -duration 5:00 '" & (POSIX path of this_item & "'"))
end process_item