Laragon Multiple MySQL Database Version Setup

Laragon Multiple MySQL Database Version.md

Pre-requisite

1. Laragon
2. Multiple DB are ready to install (look table below)
3. Unzip tools like 7zip or Winrar
4. Laragon installation path default is C:\laragon\, might be different depending on where you install this. However we will focus on laragon mysql directory folder which located on C:\laragon\bin\mysql

If you look at Laragon documentation on multiple DB it should be straight forward however i would like to make it as painless as possible with the setup

By default Laragon (Full version) comes with MySQL 8.0.* version. However we will install latest or older version of MySQL show how we switch to one another using Laragon system tray mysql version switch feature.

For this context we will use MySQL community ZIP version that does not have any debugging binary and test suite (keep the size down)

MySQL Version	Download Path	Local Data Path
5.7.44	Link	C:\laragon\data\mysql
8.0.* (Default)	N/A	C:\laragon\data\mysql-8
8.4 LTS	Link	C:\laragon\data\mysql-8.4

Steps for MySQL 8.4

1. Download and unzip the file to C:\laragon\bin\mysql. Your folder structure should look like this after extract.
2. Open command line using CMDer (default terminal by Laragon) and run:

cd C:\laragon\bin\mysql\mysql-8.4.0-winx64\bin

mysqld --initialize --datadir="C:\laragon\data\mysql-8.4" --basedir="C:\laragon\bin\mysql\mysql-8.4.0-winx64" --console

Make sure to store those password generated in the terminal for later use. We will use it to reset root password when we start to login via HeidiSQL

3. Copy my.ini (mysqld config) below to mysql 8.4 base folder and set it as read-only (to avoid Laragon override setting using old template)

4. Right click on Laragon Tray and switch to MySQL 8.4 version

5. Start services

6. Open HeidiSQL or any of your DB IDEs and start accessing the table. After first login with root username and generated password, HeidiSQL will ask for new password. Key-in your desirable new password and your are done.

my.ini

[client]
#password=your_password
port=3306
socket=/tmp/mysql.sock

[mysqld]
port=3306
socket=/tmp/mysql.sock
key_buffer_size=256M
max_allowed_packet=512M
table_open_cache=256
sort_buffer_size=1M
read_buffer_size=1M
read_rnd_buffer_size=4M
myisam_sort_buffer_size=64M
thread_cache_size=8

secure-file-priv=""
explicit_defaults_for_timestamp=1
datadir= "C:/laragon/data/mysql-8.4"
basedir= "C:/laragon/bin/mysql/mysql-8.4.0-winx64"
#default_authentication_plugin=mysql_native_password


[mysqldump]
quick
max_allowed_packet=512M

In-place upgrade from 8.0.30 to 9.1.0
Direct update is not allowed : first upgrade to 8.4.3

Download the 8.4.3 and 9.1.0 MySql zip and move the extracted folders to c:\laragon\bin\mysql

Copy, paste, save as upgrade.cmd in Laragon folder; change the second statement to setup your password; run the script and wait.

@echo off
set "pwd=mysql" 
set "root=%~dp0"
if "%root:~-1%"=="\" set "root=%root:~0,-1%"
cd /d %root%
set "data=%root%\data"
echo Kill running laragon and/or MySql server
taskkill /F /IM laragon.exe /T >nul 2>&1
call :inactive_server
rem *************************************************
set "version=8.0.30"
echo Processing MySql version %version%
set "mysql=%root%\bin\mysql\mysql-%VERSION%-winx64"
call :start_server
Echo Start MySql, change password and authentification, stop server 
echo ALTER USER 'root'@'localhost'IDENTIFIED WITH caching_sha2_password BY '%pwd%';>sql.txt 
echo shutdown;>>sql.txt&echo quit>>sql.txt
"%mysql%\bin\mysql.exe" -u root <sql.txt
echo Modify my.ini and set read-only
findstr /v default_authentication "%mysql%\my.ini" >my.ini
copy /y my.ini "%mysql%\my.ini"
attrib +R "%mysql%\my.ini"
rem
rem *************************************************
set "version=8.4.3"
echo Processing MySql version %version%
call :inactive_server
set "mysql=%root%\bin\mysql\mysql-%VERSION%-winx64"
copy /y my.ini "%mysql%\my.ini"
attrib +R "%mysql%\my.ini"
call :start_server
echo Connect on server and shutdown
"%mysql%\bin\mysqladmin.exe" -u root -p%pwd% shutdown
rem
rem *************************************************
set "version=9.1.0"
echo Processing MySql version %version%
call :inactive_server
set "mysql=%root%\bin\mysql\mysql-%VERSION%-winx64"
powershell "(Get-Content my.ini).replace('mysql-8','mysql-9')|Set-Content '%mysql%\my.ini'"
attrib +R "%mysql%\my.ini"
rd /s /q "%data%\mysql-9" >nul 2>&1 
ren "%data%\mysql-8" mysql-9
echo Connect on server and shutdown
call :start_server
"%mysql%\bin\mysqladmin.exe" -u root -p%pwd% shutdown
del my.ini, sql.txt
call :inactive_server
echo All done. Hit any key to exit.
pause >nul
goto:eof
rem *************************************************
:start_server
Echo Start MySql server
start "MySql" /d "%mysql%\bin" mysqld.exe --console
set "netstat=netstat -an|findstr /c:'3306 '|findstr 'LISTENING'
powershell "While(!(%netstat%)){'Waiting on server active';Start-Sleep 1}"
echo Server is listening
exit /b
:inactive_server
rem taskkill /F /IM mysqld.exe /T >nul 2>&1
set "get_server=Get-Process -Name mysqld -ErrorAction `SilentlyContinue"`
powershell "While(%get_server%){'Server still active';Start-Sleep 1}"
echo No mysqld process active
exit /b
pause

You can start laragon using mysql 9.1.0

That's all folks

Thank you 👍 Ben Joseph Cote 15908 59 ST. NW Edmonton, AB T5Y 2R4 tel: 250-508-4942 email: ***@***.***

…

________________________________ From: rpascolo ***@***.***> Sent: Saturday, November 30, 2024 8:04 AM To: rpascolo ***@***.***> Cc: Comment ***@***.***> Subject: Re: meorajrul/Laragon Multiple MySQL Database Version.md @rpascolo commented on this gist.

________________________________ In-place upgrade from 8.0.30 to 9.1.0 Direct update is not allowed : first upgrade to 8.4.3 Download the 8.4.3 and 9.1.0 MySql zip and move the extracted folders to c:\laragon\bin\mysql Start laragon with MySql 8.0.30 Change the password and use caching_sha2_password authentication This can be achieved by different ways : - Invoke phpmyadmin : Select Change password Enter and Re-type the new password Select Caching sh2 authentification - Click on Terminal Navigate to "C:\laragon\bin\mysql\mysql-8.0.30-winx64\bin" Enter mysql -u root -p Enter your password Enter ALTER USER 'root'@'localhost' IDENTIFIED WITH caching_sha2_password BY 'your password' Enter exit Enter exit - Use Heidisql to enter the sql statement Edit the my.ini file and remove the default_authentication_plugin=mysql_native_password line Save the my.ini file and make the my.ini file read only (important) Stop laragon Copy the my.ini to from 8.0.30 to 8.4.3 Change the MySql version to mysql-8.4.3-win64 Start All Upgrade tasks are performed (be patient) Stop laragon Copy the my.ini to from 8.4.3 to 9.1.0 Change the MySql version to mysql-9.1.0-win64 (you may change the name of the data directory and update my.ini consequently) Start All Upgrade tasks are performed (be patient) You laragon is using mysql 9.1.0 That's all folks — Reply to this email directly, view it on GitHub<https://gist.github.com/meorajrul/b57803bf1b4ddfd2f93e6ad37c3ac5f2#gistcomment-5310987> or unsubscribe<https://github.com/notifications/unsubscribe-auth/APL6CRATIMZAGC3GPZG5M3T2DHHYZBFKMF2HI4TJMJ2XIZLTSKBKK5TBNR2WLJDUOJ2WLJDOMFWWLO3UNBZGKYLEL5YGC4TUNFRWS4DBNZ2F6YLDORUXM2LUPGBKK5TBNR2WLJDHNFZXJJDOMFWWLK3UNBZGKYLEL52HS4DFVRZXKYTKMVRXIX3UPFYGLK2HNFZXIQ3PNVWWK3TUUZ2G64DJMNZZDAVEOR4XAZNEM5UXG5FFOZQWY5LFVEYTCOJUGUZTINJUU52HE2LHM5SXFJTDOJSWC5DF>. You are receiving this email because you commented on the thread. Triage notifications on the go with GitHub Mobile for iOS<https://apps.apple.com/app/apple-store/id1477376905?ct=notification-email&mt=8&pt=524675> or Android<https://play.google.com/store/apps/details?id=com.github.android&referrer=utm_campaign%3Dnotification-email%26utm_medium%3Demail%26utm_source%3Dgithub>.

Warning!!
On MySQL 9.0, the mysql_native_password plugin was removed completely.
Before upgrading MySQL, change the authentication plugin of the MySQL users (this includes the root user) to caching_sha2_password.
More info at
https://php.watch/articles/fix-php-mysql-84-mysql_native_password-not-loaded