React contexts with Reagent

React Contexts with Reagent.md

The following provide and consume Reagent components expose React contexts without fuss.

Example

(:require [example.reagent-context :as c])

;; in a component, use `provide` to supply values for contexts:
[c/provide {:app-theme {:color "blue"}}
 ;; consume one context at a time
 [c/consume :app-theme
  (fn [theme]
    [:div
      {:style {:color (:color theme)}} "Colorful Text"])]]

• Contexts can be keywords or React context instances. In the case of keywords, React context instances are created behind the scenes.
• Context values are left alone, they remain as JS or Clojure values (no coercion).
• Ratoms inside consume work as you'd expect.
• You can provide multiple contexts at the same time, but you can only c/consume one context at a time.

Prior art: Lokeh/reagent-context

reagent_context.cljs

(ns example.reagent-context
  (:require ["react" :as react]
            [reagent.core :as r]))

(defonce get-context
         (memoize
          (fn [k]
            (if (keyword? k)
              (react/createContext (munge (str k)))
              k))))

(defn provide
  "Adds React contexts to the component tree.
   `bindings` should be a map of {<keyword-or-Context>, <value-to-be-bound>}."
  [bindings & body]
  (loop [bindings (seq bindings)
         out (->> body
                  (reduce (fn [a el] (doto a (.push (r/as-element el)))) #js [])
                  (.concat #js [react/Fragment #js {}])
                  (.apply react/createElement nil))]
    (if (empty? bindings)
      out
      (recur (rest bindings)
             (let [[context-or-key v] (first bindings)
                   ^js context (get-context context-or-key)]
               (react/createElement (.-Provider context)
                                    #js {:value v}
                                    out))))))

(defn consume
  "Reads a React context value within component tree.

   `context` should be a keyword or React Context instance."
  [context f]
  (react/createElement
   (.-Consumer (get-context context))
   #js {}
   (fn [value]
     (r/as-element [f value]))))

Yes

Copyright 2018 Matthew Huebert

Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

Cheers!