PKGBUILD

# Maintainer: Anton Kalmykov <anton dot kalmykov at gmail dot com>

# To disable building of the utility application, add -DBUILD_UTILITY=OFF
# to cmake arguments and then you even can remove qt4 from depends.

_basename=airwave
pkgname=${_basename}-git
pkgver=r46.d314db4
pkgrel=1
pkgdesc="A WINE-based VST bridge, that allows to use Windows VST 2.4 plugins with Linux VST hosts."
arch=('i686' 'x86_64')
license=('MIT')
url=('https://github.com/phantom-code/airwave')
depends=('wine>=1.7' 'qt4')
makedepends=('git' 'cmake>=2.8')

if [[ $CARCH == 'x86_64' ]]; then
  makedepends+=('gcc-multilib')
fi

provides=('airwave')
conflicts=('airwave')

source=('git+https://github.com/phantom-code/airwave.git#branch=develop'
        'vstsdk360_22_11_2013_build_100.zip::steinberg://dummy')

sha256sums=('SKIP'
            '74e41da563a1c91e86677530936cb46a15f1af76b29d4c1877134cf29eafb718')

steinberg() {
  local steinberg_username='[email protected]'
  local steinberg_password='o87zYwwrBxqaZtm6ArSU'

  local cookiejar=$(mktemp)

  curl --cookie-jar $cookiejar -L \
    'http://www.steinberg.net/nc/en/company/developers/sdk_download_portal.html' >/dev/null

  sleep 1

  curl --cookie $cookiejar --cookie-jar $cookiejar --data \
    'user='$steinberg_username'&pass='$steinberg_password'&submit=Login&logintype=login&pid=0&redirect_url=' \
     -L 'http://www.steinberg.net/nc/en/company/developers/sdk_download_portal.html' >/dev/null

  sleep 1

  curl --cookie $cookiejar --cookie-jar $cookiejar -L \
    'http://www.steinberg.net/nc/en/company/developers/sdk_download_portal/vst_360_audio_plug_ins_sdk.html' >/dev/null

  sleep 1

  local url=$(curl --cookie $cookiejar --cookie-jar $cookiejar --data \
    'vst_status=0&vst_produkte=&vst_produkte_neu=&sdk_daten_speichern=Download VST SDK now' \
     -L 'http://www.steinberg.net/nc/en/company/developers/sdk_download_portal/vst_360_audio_plug_ins_sdk.html' \
     | grep -Pi 'VST.*?SDK</a>' | sed -r 's/^.*href="([^"]+).*$/\1/' | sed -re 's/&amp;/\&/g')

  sleep 1

  curl -o "$1" --cookie $cookiejar --cookie-jar $cookiejar -L \
    'http://www.steinberg.net/'"$url"

  rm $cookiejar
}

export -f steinberg

DLAGENTS=("${DLAGENTS[@]}"
  'steinberg::/usr/bin/bash -c '\''steinberg %o %u'\'''
)

pkgver()
{
  cd "${_basename}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare()
{
  msg 'Moving VST SDK files...'
  mv "$srcdir/VST3 SDK" "$srcdir/vstsdk2.4"
}

build()
{
  cd "${_basename}"

  [[ -d build ]] && rm -rf build
  mkdir build && cd build

  cmake .. -DCMAKE_INSTALL_PREFIX="/usr"       \
           -DCMAKE_BUILD_TYPE="Release"        \
           -DVSTSDK_PATH="${srcdir}/vstsdk2.4"
  make
}

package()
{
  cd "${_basename}/build"
  make install DESTDIR="${pkgdir}/"

  # Install the documentation
  install -D -m644 "${srcdir}/${_basename}/README" \
                   "${pkgdir}/usr/share/doc/${_basename}/README"

  # Install the license
  install -D -m644 "${srcdir}/${_basename}/LICENSE" \
                   "${pkgdir}/usr/share/licenses/${_basename}/LICENSE"
}