How to parse json into a serializable HashMap in Jenkins Groovy

parseJson.groovy

@NonCPS
def parseJson(txt){
	def lazyMap = new groovy.json.JsonSlurper().parseText(txt)
	def map = [:]
	for ( prop in lazyMap ) {
    	map[prop.key] = prop.value
	}
	return map;
}

this works, thanks
but it works only when the map is flat, not handling nested LazyMap

This is a way to do it recursively:

  @NonCPS
  @CompileStatic
  static def convertLazyMapToLinkedHashMap(def value) {
    if (value instanceof LazyMap) {
      Map copy = [:]
      for (pair in (value as LazyMap)) {
        copy[pair.key] = convertLazyMapToLinkedHashMap(pair.value)
      }
      copy
    } else {
      value
    }
  }

What about https://jenkins.io/doc/pipeline/steps/pipeline-utility-steps/#readjson-read-json-from-files-in-the-workspace ?

What about https://jenkins.io/doc/pipeline/steps/pipeline-utility-steps/#readjson-read-json-from-files-in-the-workspace ?

You saved me, thanks!

Based on @diroussel code, I made an improved version:

@NonCPS
def toToLinkedHashMap(def obj) {
    if (obj instanceof groovy.json.internal.LazyValueMap) {
        Map copy = [:];
        for (pair in (obj as Map)) {
            copy.put(pair.key, toToLinkedHashMap(pair.value));
        }
        return copy;
    }
    if (obj instanceof groovy.json.internal.ValueList) {
        List copy = [];
        for (item in (obj as List)) {
            copy.add(toToLinkedHashMap(item));
        }
        return copy;
    }
    return obj;
}

Another small improvement (use generic Map and List rather than specific implementations):

@NonCPS
def toSerializable(def obj) {
    if (obj instanceof Map) {
        Map copy = [:]
        for (pair in (obj as Map)) {
            copy.put(pair.key, toSerializable(pair.value))
        }
        return copy
    }
    if (obj instanceof List) {
        List copy = []
        for (item in (obj as List)) {
            copy.add(toSerializable(item))
        }
        return copy
    }
    return obj
}

def foo( String txt ){
  def object = new groovy.json.JsonSlurper().parseText(txt)
  Map.isCase( object )  ? object.collectEntries {[ it.key, it.value ]} :
  List.isCase( object ) ? object.collect { it } : object
}

@marslo nice! you forgot recursion though