Build Gradle script that generates jar file with manifest classpath pointing to dependencies in subfolder /lib. (gradle, groovy, kotlin, spring)

build.gradle

plugins {
    id 'org.hidetake.ssh' version '2.9.0'
    id 'org.jetbrains.kotlin.jvm' version '1.3.11'
    id 'org.springframework.boot' version '2.1.2.RELEASE'
    id 'io.spring.dependency-management' version "1.0.6.RELEASE"
}

group 'App Group'
version '1.0.0'

repositories {
    mavenCentral()
}

dependencies {
    compile 'org.jetbrains.kotlin:kotlin-stdlib-jdk8'
    compile "org.jetbrains.kotlin:kotlin-reflect:1.3.11"

    compile 'org.springframework.boot:spring-boot-starter-web'
}

// Copy dependencies to 'lib' directory
task copyRuntimeLibs(type: Copy) {
    into "$buildDir/libs/lib/"
    from configurations.compile
}
// attach to assemble task
assemble.dependsOn copyRuntimeLibs

jar {
    manifest {
        attributes(
                'Main-Class': 'ApplicationKt',
                'Class-Path': configurations.compile.collect { 'lib/' + it.getName() }.join(' ')
        )
    }
}

compileKotlin {
    kotlinOptions.jvmTarget = '1.8'
}
compileTestKotlin {
    kotlinOptions.jvmTarget = '1.8'
}