gradle

build.gradle

allprojects {
    group = "pe.com.mycompany.psi"
    ext.providerName = "arnoldgamarram"
    ext.providerId = "ws.arnoldgamarram"
    ext.commonsIoVersion = "2.4"
    ext.commonsLangVersion = "3.4"
    ext.javaVersion = "1.8"
    ext.janinoVersion = "2.7.8"
    ext.jeeApiVersion = "6.0"
    ext.jtopenVersion = "8.6"
    ext.junitVersion = "4.12"
    ext.logbackVersion = "1.1.3"
    ext.mailApiVersion = "1.4.7"
    ext.mybatisVersion = "3.3.0"
    ext.mybatisSpringVersion = "1.2.3"
    ext.mockitoVersion = "2.0.31-beta"
    ext.servletApiVersion = "3.0.1"
    ext.slf4jVersion = "1.7.12"
    ext.springFrameworkVersion = "4.2.2.RELEASE"
    ext.thymeleafVersion = "2.1.4.RELEASE"
    ext.jacksonVersion="1.9.0"
    ext.jsonVersion = "20141113"
    ext.javaFacetVersion = javaVersion
    ext.javascriptFacetVersion = "1.0"
    ext.jeeFacetVersion = jeeApiVersion
    ext.runtimeName = "JBoss EAP 6.1+ Runtime"
    ext.webModuleFacetVersion = "3.0"
    ext.itextpdfVersion = "2.1.7"
    
	
    ext.webServicesPaymentsContextPath = "WSEjecutarpago"
    
    
    repositories {mavenCentral()}
}

subprojects {
    apply plugin: "java"
    apply plugin: "eclipse-wtp"

    tasks.withType(JavaCompile) { options.encoding = "UTF-8" }

    compileJava {
        sourceCompatibility = "${javaVersion}"
        targetCompatibility = "${javaVersion}"
    }

    configurations {
        all*.exclude group: "commons-logging", module: "commons-logging" 
        all*.exclude group: "org.bouncycastle", module: "bcprov-jdk14"
        all*.exclude group: "org.bouncycastle", module: "bcmail-jdk14"
    }

    plugins.withType(WarPlugin) {
        war {  jar.enabled = false  }

        eclipse {
            wtp {
                facet {
                    facets = []
                    facet name: "java", type: "fixed"
                    facet name: "jst.web", type: "fixed"
                    facet name: "wst.jsdt.web", type: "fixed"
                    facet name: "java", version: "${javaFacetVersion}"
                    facet name: "jst.web", version: "${webModuleFacetVersion}"
                    facet name: "wst.jsdt.web", version: "${javascriptFacetVersion}"
                }
            }
        }
    }

    plugins.withType(EarPlugin) {
        ear { group = "pe.com.mycompany.psi" }

        eclipse {
            wtp {
                facet {
                    facets = []
                    facet name: "jst.ear", type: "fixed"
                    facet name: "jst.ear", version: "${jeeFacetVersion}"
                }
                component {
                    resource sourcePath: "/", deployPath: "/", tag: "defaultRootSource"
                }
            }
        }
    }
}


project("mycompany-psi-services-pago-web") {
    apply plugin: "war"

    dependencies {
        compile "ch.qos.logback:logback-classic:${logbackVersion}"
        compile "org.codehaus.janino:janino:${janinoVersion}"
        compile "org.slf4j:jcl-over-slf4j:${slf4jVersion}"
        compile "org.slf4j:slf4j-api:${slf4jVersion}"
        compile "org.springframework:spring-context:${springFrameworkVersion}"
        providedCompile "javax.servlet:javax.servlet-api:${servletApiVersion}"
        testCompile "junit:junit:${junitVersion}"
        testCompile "org.mockito:mockito-core:${mockitoVersion}"
        testCompile "org.springframework:spring-test:${springFrameworkVersion}"
        testCompile project(":mycompany-psi-adapters-business-web")
    }
    
    eclipse.wtp.component.contextPath = "${webServicesPaymentsContextPath}"
}