Reason Web Audio

Audio.re

module AudioDestinationNode = {
  type t;
};

module OscillatorNode = {
  type t;
  
  [@bs.send]
  external connect: (t, AudioDestinationNode.t) => unit = "connect";
};

module AudioContext = {
  type t;

  [@bs.scope "window"] [@bs.new]
  external unsafeMakeAudioContext: unit => t = "AudioContext";

  [@bs.scope "window"] [@bs.new]
  external unsafeMakeWebkitAudioContext: unit => t = "webkitAudioContext";
  
  [@bs.get]
  external getDestination: t => AudioDestinationNode.t = "destination";
  
  [@bs.send]
  external createOscillator: t => OscillatorNode.t = "createOscillator";

  let make: unit => option(t) =
    () =>
      try (Some(unsafeMakeAudioContext())) {
      | _ =>
        try (Some(unsafeMakeWebkitAudioContext())) {
        | _ => None
        }
      };
};

switch (AudioContext.make()) {
| None => Js.log("Uh oh, no audio context")
| Some(ctx) =>
  open AudioContext;
  open OscillatorNode;
  
  let oscillatorNode = ctx->createOscillator;
  let destination = ctx->getDestination;
  oscillatorNode->connect(destination);
};