Batch script to execute a given command repeatedly. Waits specified amount of time between two executions.

listen.bat

@echo off

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: This script executes given command repeatedly.
:: Waits specified amount of time between two executions.
:: First parameter MUST be sleep time.
:: Rest of the parameters will be executed as a command.
:: This script relies on sleep command from GnuWin32 package.
:: 
:: usage: (1 minute = 60 seconds intervals. More info: sleep --help)
::    listen 60  grep -w needle "haystack.txt"
::    listen 60s grep -w needle "haystack.txt"
::    listen  1m grep -w needle "haystack.txt"
::
:: @author: [email protected]
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: First argument is expected to be sleep time
set SLEEP_TIME=%1

:: Other arguments will be a command with or without some parameter(s)
set command=
:init
shift
if [%1]==[] goto exec
set command=%command% %1
goto init

:exec
	call %command%
	sleep %SLEEP_TIME%
goto exec