Set session with Absinthe mutation

cookie_helper.ex

defmodule MyAppWeb.Api.CookieHelper do
  @behaviour Absinthe.Middleware

  def init(default), do: default

  def call(%{value: %{data: %{access_token: token}}} = resolution, _config)
      when is_binary(token) do
    update_context(resolution, :set_cookie, token)
  end

  def call(%{value: %{user_signed_out: true}} = resolution, _) do
    update_context(resolution, :set_cookie, nil)
  end

  def call(res, _), do: res

  defp update_context(resolution, key, value) do
    Map.update!(resolution, :context, fn ctx ->
      Map.put(ctx, key, value)
    end)
  end

  def maybe_put_cookie(conn, %Absinthe.Blueprint{} = blueprint) do
    case blueprint.execution.context do
      %{set_cookie: nil} ->
        Plug.Conn.delete_resp_cookie(conn, "access_token")

      %{set_cookie: token} ->
        Plug.Conn.put_resp_cookie(conn, "access_token", token)

      _ ->
        conn
    end
  end

  def maybe_put_cookie(conn, _) do
    conn
  end
end

session_resolvers.ex

defmodule MyAppWeb.Api.Resolvers.SessionResolvers do
  alias MyApp.Users
  alias MyApp.Users.User
  alias MyApp.Token

  def sign_in(%{employee_no: employee_no, password: password}, _) do
    case Users.authenticate_user_by_employee_no_password(employee_no, password) do
      {:ok, %User{} = user} ->
        {:ok,
         %{success: true, data: %{user: user, access_token: Token.issue_token_for_user(user)}}}

      _ ->
        {:ok, %{success: false, errors: %{"message" => "您所輸入的電子郵件或密碼有誤。"}}}
    end
  end

  def sign_out(_, _) do
    {:ok, %{success: true, user_signed_out: true, user: nil}}
  end
end

session_types.ex

defmodule MyAppWeb.Api.Types.Sessions do
  use Absinthe.Schema.Notation
  alias MyAppWeb.Api.Resolvers.SessionResolvers

  object :session_mutation_response do
    field :success, non_null(:boolean)
    field :errors, :json
    field :data, :session_data
  end

  object :session_data do
    field :access_token, non_null(:string)
    field :user, non_null(:user)
  end

  object :session_mutations do
    field :sign_in, non_null(:session_mutation_response) do
      arg(:employee_no, non_null(:string))
      arg(:password, non_null(:string))

      resolve(&SessionResolvers.sign_in/2)
      middleware(MyAppWeb.Api.CookieHelper)
    end

    field :sign_out, non_null(:session_mutation_response) do
      resolve(&SessionResolvers.sign_out/2)
      middleware(MyAppWeb.Api.CookieHelper)
    end
  end
end