sparkline.coffee

class Sparkline
  constructor : (elem, @data, @opts)->
    @opts ||= {}
    _.extend(@opts, Sparkline.defaults)
    @width = $(elem).width()
    @height = $(elem).height()
    @graph = d3.select(elem).append("svg:svg").attr("width", @width).attr("height", @height)
    @data ||= [0]
    @setScale()

    @line = d3.svg.line().interpolate(@opts.interpolate)
    @line.x (d, i)=>
      @scaleX(i)
    @line.y (d)=>
      @scaleY(d)

    @path = @graph.append("svg:path").attr("d", @line(@data))

  redraw : ->
    @graph.selectAll("path")
      .data([@data])
      .attr("transform", "translate(" + @scaleX(1) + ")")
      .attr("d", @line)
      .transition()
      .ease(@opts.ease)
      .duration(@opts.duration)
      .attr("transform", "translate(" + @scaleX(0) + ")")
    
  setScale : ->
    @scaleX = d3.scale.linear().domain([0, @data.length]).range([-5, @width])
    @scaleY = d3.scale.linear().domain([_.max(@data), _.min(@data)]).range([0, @height])

  pushData : (value)->
    @data.push(value)
    @setScale()
    @redraw()

Sparkline.defaults =
  transitionTime : 1000
  ease : 'linear'
  interpolate : 'basis'

window.Sparkline = Sparkline