Flash Message in Ember http://coderberry.me/blog/2013/06/20/using-flash-messages-with-emberjs/

application.emblem

render "flash"

flash.coffee

App.CONF =
  flash_display_time = 2000

App.FlashMessage = Ember.Object.extend
  type: 'info'
  value: null

App.FlashView = Ember.View.extend
  classNameBindings: ["className","isInfo", "isWarn", "isError" ]
  className: 'flash'
  isInfo: (->
    @get('controller.message.type') == 'info'
  ).property('controller.message.type')
  isWarn: (->
    @get('controller.message.type') == 'warn'
  ).property('controller.message.type')
  isError: (->
    @get('controller.message.type') == 'error'
  ).property('controller.message.type')

  messageObserver:((sender, key, value, rev)->
    @fadeUp()
    Em.run.debounce(@, @fadeDown, App.CONF.flash_display_time+10)
  ).observes('controller.message')

  fadeTo: (opacity)->
    unless Em.isNone @.$()
      @.$().animate
        opacity: opacity
        , 500
  fadeUp: ->
    @fadeTo(1.0)
  fadeDown: ->
    @fadeTo(0.0)
   
App.FlashController = Ember.ObjectController.extend
  message: null
  init: ->
    App.FlashQueue.addArrayObserver(@)
    @_super()
  willDestroy: ->
    App.FlashQueue.removeArrayObserver(@)
    @_super()
  arrayWillChange: (observeObj, start, removeCount, addCount)->

  arrayDidChange: (observeObj, start, removeCount, addCount)->
    if addCount > 0
      @showMessages() 
  showMessages: ->
    Ember.run.throttle(@, @showMessage, App.CONF.flash_display_time, true)

  showMessage: ->
    fmsg = App.FlashQueue.shiftObject()
    unless Em.isNone(fmsg)
      #show current message
      @set('message', fmsg)
      #prepare to show next message
      Em.run.later(@, @showMessages, App.CONF.flash_display_time)

App.FlashQueue = Ember.ArrayProxy.create
  content: Em.A()
  error: (msg)->
    @addMessage('error', msg)
  warn: (msg)->
    @addMessage('warn', msg)
  info: (msg)->
    @addMessage('info', msg)
  addMessage: (type, msg)->
    @pushObject(App.FlashMessage.create
      value: msg
      type: type
    )

flash.emblem

message.value

Call App.FlashQueue.addMessage multiple times and messages are queued up. No fade between display of queued messages.