gistfile1.txt

# $Id$
# Maintainer: Vesa Kaihlavirta <[email protected]>
# Maintainer: Alexander Rødseth <[email protected]>
# Contributor: Andres Perera <andres87p gmail>
# Contributor: Matthew Bauer <[email protected]>
# Contributor: Christian Himpel <chressie at gmail dot com>
# Contributor: Mike "str1ngs" Rosset

pkgname=go
pkgver=1
pkgrel=4
epoch=2
pkgdesc='Google Go compiler and tools (release version)'
arch=('x86_64' 'i686')
url="http://golang.org/"
license=('custom')
depends=('perl' 'ed' 'gawk')
makedepends=('mercurial' 'inetutils')
options=('!strip' '!emptydirs')
source=( "http://go.googlecode.com/files/go.go${pkgver}.src.tar.gz")
sha1sums=('6023623d083db1980965335b8ac4fa8b428fa484')

PKGEXT='.pkg.tar.gz'

build() {
  cd $srcdir/go/src
  export GOROOT_FINAL=/usr/lib/go
  ./make.bash
}

package() {
  mkdir -p $pkgdir/usr/{lib,bin}
  
  # install goroot to pkgdir/$GOROOT_FINAL
  cp -a go $pkgdir/usr/lib/

  cd go
  # misc and contrib files
  install -Dm644 LICENSE $pkgdir/usr/share/licenses/go/LICENSE
  install -Dm644 misc/bash/go $pkgdir/etc/bash_completion.d/go
  install -Dm644 misc/emacs/go-mode-load.el \
    $pkgdir/usr/share/emacs/site-lisp/go-mode-load.el
  install -Dm644 misc/emacs/go-mode.el \
    $pkgdir/usr/share/emacs/site-lisp/go-mode.el
  install -Dm644 misc/vim/ftdetect/gofiletype.vim \
    $pkgdir/usr/share/vim/vimfiles/ftdetect/gofiletype.vim
  install -Dm644 misc/vim/syntax/go.vim \
    $pkgdir/usr/share/vim/vimfiles/syntax/go.vim

  # symlink go commands to /usr/bin
  for i in go gofmt godoc; do
    ln -s /usr/lib/go/bin/$i $pkgdir/usr/bin/$i
  done
}

# vim:set ts=2 sw=2 et: