Decoder for a file/log that contains Base64-encoded words

decode_base64_log

#!/usr/bin/perl -w
use strict;
use diagnostics;
use MIME::Base64;
 
# Decoder for a file/log that contains Base64-encoded words
 
binmode STDIN, ':utf8';
binmode STDOUT, ':utf8';
 
while (my $line1 = <STDIN>){
        chomp $line1;
        # Work on a copy of the original line
        my $line2 = $line1;
        # split along non-base64 charset characters
        my @words = split /[^A-Za-z0-9+\/=]/, $line2;
        foreach my $encoded1 (@words){
                # Decode each base64 string
                if ($encoded1 =~ /^[A-Za-z0-9+\/=]+$/){
                        my $decoded = decode_base64($encoded1);
                        # Strip all nonprintable characters that were decoded
                        # from invalid Base64 inputs (which usually are many)
                        $decoded =~ s/[^[:print:]]//g;
                        # Encode back to Base64 to check for plausibility
                        my $encoded2 = encode_base64($decoded);
                        chomp $encoded2;
                        # Replace string if reencoded is same as original
                        if ($encoded1 eq $encoded2){
                                $line2 =~ s/\Q$encoded1\E/"$decoded"/;
                        }
                }
        }
        #print "\n$line1\n";
        print "$line2\n";
}