EnchantFromAmber shooting game example

EcShootingGameExample.st

EcSprite subclass: #EcExampleApple
  instanceVariableNames: ''
	package: 'Enchant-Examples'!

!EcExampleApple methodsFor: 'initialization'!

initialize
	self extent: 16@16.
	self imageName: 'icon0.png'.
	self frame: 15.
! !

EcSprite subclass: #EcExampleEnemyBear
	instanceVariableNames: ''
	package: 'Enchant-Examples'!

!EcExampleEnemyBear methodsFor: 'initialization'!

initialize
	self extent: 32@32.
	self imageName: 'chara1.png'.
	self frame: 15.
! !

EcSprite subclass: #EcExampleShooterBear
	instanceVariableNames: ''
	package: 'Enchant-Examples'!

!EcExampleShooterBear methodsFor: 'initialization'!

initialize
	self extent: 32@32.
	self imageName: 'chara1.png'.
	self frame: 5.
! !

EcGameProgram subclass: #EcShootingGameExample
	instanceVariableNames: 'score'
	package: 'Enchant-Examples'!

!EcShootingGameExample methodsFor: 'accessing'!

score
	^score
! !

!EcShootingGameExample methodsFor: 'actions'!

init
	super init.
	score := 0
!

prepareBeforeLoad
	self game assetsBasePath: './game-img/'.
	self game preloadAssets: #('chara1.png' 'icon0.png').
	self game fps: 20.
!

prepareOnLoad
	| scene bear enemy |
	scene := self game rootScene.
	
	bear := EcExampleShooterBear new.
	scene add: bear.
	bear tl delay: (self game fps * 20); then: [self stop].
	scene onTouchMove: [:event | bear y: event localY].
	
	scene tl 
		then: [ 
			enemy := EcExampleEnemyBear new.
			enemy scaleX: -1.
			enemy moveTo: (self gameWidth@ self gameHeight atRandom).
			enemy tl moveBy: ((self gameWidth + 40) negated@0) time: 160.
			scene add: enemy
		]; delay: 30; loop.
	
	scene onTouchStart: [:event | | apple |
		bear y: event localY.
		apple := EcExampleApple new.
		apple moveTo: (bear width@ (bear y + (bear height / 2))).
		apple tl moveBy: (self gameWidth@0) time: 30.
		apple onEnterFrame: [ | enemies|
			enemies := scene entitiesOf: EcExampleEnemyBear.
			apple intersectAnyOf: enemies ifTrue: [:enem |
				scene remove: enem; remove: apple.
				self incrementScore
			]
		].
		scene add: apple
	].
! !

!EcShootingGameExample methodsFor: 'private'!

incrementScore
	score := score + 1
!

stop
	window alert: ('Game Over!! Score: ', self score).
	super stop
! !

Nice example! The shooting mechanics and overall structure make it a useful reference for anyone experimenting with similar gameplay systems. It's always helpful to study different implementations to improve controls, aiming, and player feedback. If you're also looking for standchillow download android, be sure to use trusted and official sources to get the latest version safely.