Pdefc / Pbindefc / Pkeyc classes

Pdefc.sc

// Same as Pdef, but it collects last event on global `allEvents` dictionary
Pdefc : Pdef {
    classvar <>allEvents;

    *initClass {
        allEvents = IdentityDictionary.new;
    }

    *new { arg key, item;
        // Replace Pbind source for a Pcollect that stores
        // currently played event on allEvents dictionary.
        item = item.collect { |e|
            allEvents.put(key, e);
            e
        }
        ^super.new(key, item)
    }
}

// Same as Pbindef, but it collects last event on Pdef.allEvents dictionary
Pbindefc : Pbindef {
    *new { arg key ... pairs;
        var pat, pbind;
        pat = super.new(key, *pairs);

        pbind = pat.source.source;
        // Do the same thing as in Pdefc.new
        pbind.source = pbind.source.collect { |e|
            Pdefc.allEvents.put(key, e);
            e
        };

        ^pat
    }
}

// Same as Pkey, but it accepts a Pdefc/Pbindefc key as first argument
Pkeyc : Pattern {
	var	<>defKey, <>key;
	*new { arg defKey, key;
		^super.newCopyArgs(defKey, key)
	}
	storeArgs { ^[key] }
	asStream {
        ^FuncStream({ this.currentEvent[key] })
	}
    currentEvent {
        var dict;
        dict = Pdefc.allEvents[defKey];
        dict.isNil.if{dict = ()};
        ^dict
    }
}