macports-swatch-PKGBUILD

# Maintainer: KAWAHARA Masashi <anthrax at unixuser.org>
# Contributor: Kevin Piche <kevin at archlinux.org>
# Contributor: K. Piche <kpiche at rogers.com>
# Contributor: Mark Grimes <mgrimes at peculier.com>

pkgname=swatch
pkgver=3.2.3
pkgrel=2
pkgdesc="The active log file monitoring tool"
_dist=swatch
arch=(i686 x86_64)
license=('GPL')
url="http://swatch.sourceforge.net/"
depends=('perl-date-calc' 'perl-date-manip' 'perl-file-tail' 'perl-timedate' 'perl>=5.10.0')
source=(http://downloads.sourceforge.net/sourceforge/swatch/$pkgname-$pkgver.tar.gz)
options=(!emptydirs)
md5sums=('1162f1024cf07fc750ed4960d61ac4e8')

build() {
  cd "$srcdir/$_dist-$pkgver"
  unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  /usr/bin/perl Makefile.PL
  make
}

check() {
  cd "$srcdir/$_dist-$pkgver"
  unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1
  make test
}

package() {
  cd "$srcdir/$_dist-$pkgver"
  unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
  make install INSTALLDIRS=vendor DESTDIR="$pkgdir"

  # remove perllocal.pod and .packlist
  find ${pkgdir} -name perllocal.pod -delete
  find ${pkgdir} -name .packlist -delete
}